Universidad Autónoma Metropolitana
Autor : Jorge Garza

Oscilador armónico

Después del cambio de variable z = α x la ecuación de Schroedinger del oscilador armónico toma la forma
-(((d^2)ψ)/(dz^2))+(z^2)ψ=λψ
y la solución es
ψ=(Subscript[C, n])Hermite(z,n)(e^(-z^2/2))
donde (Subscript[C, n]) es una constante de normalización y Hermite es un polinomio de Hermite de orden n.

Definición de las soluciones

solucion[n_,z_]:=cn*HermiteH[n,z]Exp[-z^2/2]

El valor de cn para n =0, 1, 2, 3 y 4 se obtiene de

Solve[Integrate[solucion[0,z]^2, {z,-Infinity,Infinity}]==1,cn]

Solve[Integrate[solucion[1,z]^2, {z,-Infinity,Infinity}]==1,cn]

Solve[Integrate[solucion[2,z]^2, {z,-Infinity,Infinity}]==1,cn]

Solve[Integrate[solucion[3,z]^2, {z,-Infinity,Infinity}]==1,cn]

Solve[Integrate[solucion[4,z]^2, {z,-Infinity,Infinity}]==1,cn]

normalizacion[n_]:=Sqrt[1/(2^n Factorial[n]Sqrt[Pi])];
phi[n_,z_]:=normalizacion[n]HermiteH[n,z]Exp[-z^2/2]

Es claro que la función se encuentra normalizada

estado=0;
Integrate[phi[estado,z]phi[estado,z],{z,-Infinity,Infinity}]

y entre diferentes funciones son ortogonales

estado1=0;
estado2=1;
Integrate[phi[estado1,z]phi[estado2,z],{z,-Infinity,Infinity}]

Gráficas

Definir varios valores del estado de interés

estado=0;
phi[estado,z]
Plot[phi[estado,z],{z,-5,5}]
Clear[estado];

Valores esperados

Obtengamos el valor esperado de la energía potencial

<V>=∫ψ(z)(z^2)ψ(z)dz

potencial[n_]:=Integrate[phi[n,z]z^2 phi[n,z],{z,-Infinity,Infinity}]

Y de la energía cinética

<T> =-∫ψ d^2ψ/dz^2d

cinetica[n_]:=-Integrate[phi[n,z]*D[phi[n,z],{z,2}],{z,-Infinity,Infinity}]

estado=0;
potencial[estado]
cinetica[estado]
potencial[estado]+cinetica[estado]

De aquí que λ tiene la expresión

λ[n_]:=2*n+1

Se puede graficar la función de onda junto al potencial y su respectiva energía

estado=0;
Plot[{phi[estado,z]^2+λ[estado],z^2,λ[estado]},{z,-5,5},PlotRange->{0,λ[estado]+1}]

Es importante discutir en estas gráficas el tunelaje que exhibe la función de onda.

Reglas de selección

μ=∫(Subscript[ψ, ν])(z)z (Subscript[ψ, λ])(z)\[DifferentialD]z

μ[n1_,n2_]:= Integrate[phi[n1,z]z phi[n2,z],{z,-Infinity,Infinity}]

μ[2,1]